Initial import.initialbase

21 files changed, 413 insertions, 0 deletions

diff --git a/aclocal/bsp-alias.m4 b/aclocal/bsp-alias.m4
new file mode 100644
index 0000000..8a9b21a
--- /dev/null
+++ b/aclocal/bsp-alias.m4
@@ -0,0 +1,22 @@
+dnl
+dnl  $Id$
+dnl 
+
+dnl _RTEMS_BSP_ALIAS(BSP_ALIAS,RTEMS_BSP_FAMILY)
+dnl Internal subroutine to RTEMS_BSP_ALIAS
+AC_DEFUN([_RTEMS_BSP_ALIAS],
+[# account for "aliased" bsps which share source code
+      for bsp_cfgs in `ls "$srcdir"/"$RTEMS_TOPdir"/c/src/lib/libbsp/"$RTEMS_CPU"/*/"make/custom/$1.cfg" 2>/dev/null`; do
+        $2=`echo "$bsp_cfgs" | sed \
+          -e "s,^$srcdir/$RTEMS_TOPdir/c/src/lib/libbsp/$RTEMS_CPU/,," \
+          -e "s,/make/custom/.*\.cfg$,,"`
+        break
+      done
+])
+
+dnl RTEMS_BSP_ALIAS(BSP_ALIAS,RTEMS_BSP_FAMILY)
+dnl convert a bsp alias $1 into its bsp directory RTEMS_BSP_FAMILY
+AC_DEFUN([RTEMS_BSP_ALIAS],
+[_RTEMS_BSP_ALIAS(m4_if([$1],,[$RTEMS_BSP],[$1]),
+  m4_if([$2],,[RTEMS_BSP_FAMILY],[$2]))]
+)
diff --git a/aclocal/canonical-target-name.m4 b/aclocal/canonical-target-name.m4
new file mode 100644
index 0000000..ea55376
--- /dev/null
+++ b/aclocal/canonical-target-name.m4
@@ -0,0 +1,25 @@
+dnl
+dnl $Id$
+dnl
+
+dnl canonicalize target cpu
+dnl NOTE: Most rtems targets do not fullfil autoconf's
+dnl target naming conventions "processor-vendor-os"
+dnl Therefore autoconf's AC_CANONICAL_TARGET will fail for them
+dnl and we have to fix it for rtems ourselves 
+
+AC_DEFUN([RTEMS_CANONICAL_TARGET_CPU],
+[
+AC_CANONICAL_TARGET
+AC_MSG_CHECKING(rtems target cpu)
+case "${target}" in
+  no_cpu-*rtems*)
+        RTEMS_CPU=no_cpu
+	;;
+  *) 
+	RTEMS_CPU=`echo $target | sed 's%^\([[^-]]*\)-\(.*\)$%\1%'`
+	;;
+esac
+AC_SUBST(RTEMS_CPU)
+AC_MSG_RESULT($RTEMS_CPU)
+])
diff --git a/aclocal/check-bsps.m4 b/aclocal/check-bsps.m4
new file mode 100644
index 0000000..27a4c41
--- /dev/null
+++ b/aclocal/check-bsps.m4
@@ -0,0 +1,27 @@
+dnl $Id$
+
+dnl Report all available bsps for a target within the source tree
+dnl
+dnl RTEMS_CHECK_BSPS(bsp_list)
+AC_DEFUN([RTEMS_CHECK_BSPS],
+[
+AC_REQUIRE([RTEMS_CANONICAL_TARGET_CPU])dnl sets RTEMS_CPU, target
+AC_REQUIRE([RTEMS_TOP])dnl sets RTEMS_TOPdir
+
+AC_MSG_CHECKING([for available BSPs])
+  $1=
+  for bsp_spec in `ls "$srcdir/$RTEMS_TOPdir/c/src/lib/libbsp/$RTEMS_CPU"/*/bsp_specs 2>/dev/null`; do
+    bsp_family=`echo "$bsp_spec" | sed \
+      -e "s,^$srcdir/$RTEMS_TOPdir/c/src/lib/libbsp/$RTEMS_CPU/,," \
+      -e "s,/bsp_specs$,,"`
+    for bsp_cfgs in `ls "$srcdir/$RTEMS_TOPdir/c/src/lib/libbsp/$RTEMS_CPU/$bsp_family/make/custom/"*.cfg 2>/dev/null`; do
+      bsp_cfg=`echo "$bsp_cfgs" | sed \
+        -e "s,^$srcdir/$RTEMS_TOPdir/c/src/lib/libbsp/$RTEMS_CPU/$bsp_family/make/custom/,," \
+        -e "s,\.cfg$,,"`
+      $1="[$]$1 $bsp_cfg"
+    done
+  done
+  AS_IF([test -z "[$]$1"],
+    [AC_MSG_RESULT([none])],
+    [AC_MSG_RESULT([$]$1)])
+])dnl
diff --git a/aclocal/check-custom-bsp.m4 b/aclocal/check-custom-bsp.m4
new file mode 100644
index 0000000..c4ea9d4
--- /dev/null
+++ b/aclocal/check-custom-bsp.m4
@@ -0,0 +1,19 @@
+dnl $Id$
+
+AC_DEFUN([_RTEMS_CHECK_CUSTOM_BSP],[
+AC_REQUIRE([RTEMS_CANONICAL_TARGET_CPU])dnl sets RTEMS_CPU, target
+AC_REQUIRE([RTEMS_TOP])dnl sets RTEMS_TOPdir
+  $2=
+  for i in \
+    `ls "${srcdir}/${RTEMS_TOPdir}/c/src/lib/libbsp/${RTEMS_CPU}"/*/make/custom/$1 2>/dev/null`;
+  do
+    AS_IF([test -r $i],[
+      $2="$i"
+      break;
+    ])
+  done
+])
+
+AC_DEFUN([RTEMS_CHECK_CUSTOM_BSP],[
+  _RTEMS_CHECK_CUSTOM_BSP([[$]$1],[BSP_FOUND])
+])
diff --git a/aclocal/enable-cxx.m4 b/aclocal/enable-cxx.m4
new file mode 100644
index 0000000..8648743
--- /dev/null
+++ b/aclocal/enable-cxx.m4
@@ -0,0 +1,13 @@
+dnl $Id$
+
+AC_DEFUN([RTEMS_ENABLE_CXX],
+[
+AC_ARG_ENABLE(cxx,
+[AS_HELP_STRING([--enable-cxx],
+[enable C++ support and build the rtems++ library])],
+[case "${enable_cxx}" in
+  yes) RTEMS_HAS_CPLUSPLUS=yes ;;
+  no) RTEMS_HAS_CPLUSPLUS=no   ;;
+  *)  AC_MSG_ERROR(bad value ${enableval} for enable-cxx option) ;;
+esac], [RTEMS_HAS_CPLUSPLUS=no])
+])
diff --git a/aclocal/enable-multiprocessing.m4 b/aclocal/enable-multiprocessing.m4
new file mode 100644
index 0000000..175de9c
--- /dev/null
+++ b/aclocal/enable-multiprocessing.m4
@@ -0,0 +1,13 @@
+dnl $Id$
+
+AC_DEFUN([RTEMS_ENABLE_MULTIPROCESSING],
+[
+AC_ARG_ENABLE(multiprocessing,
+[AS_HELP_STRING([--enable-multiprocessing],
+[enable multiprocessing interface])],
+[case "${enable_multiprocessing}" in 
+  yes) ;;
+  no) ;;
+  *)  AC_MSG_ERROR(bad value ${enableval} for enable-multiprocessing option) ;;
+esac],[enable_multiprocessing=no])
+])
diff --git a/aclocal/enable-networking.m4 b/aclocal/enable-networking.m4
new file mode 100644
index 0000000..df02ef2
--- /dev/null
+++ b/aclocal/enable-networking.m4
@@ -0,0 +1,15 @@
+dnl $Id$
+
+AC_DEFUN([RTEMS_ENABLE_NETWORKING],
+[
+## AC_BEFORE([$0], [RTEMS_CHECK_NETWORKING])dnl
+
+AC_ARG_ENABLE(networking,
+[AS_HELP_STRING([--enable-networking],[enable TCP/IP stack])],
+[case "${enableval}" in
+  yes) RTEMS_HAS_NETWORKING=yes ;;
+  no) RTEMS_HAS_NETWORKING=no ;;
+  *)  AC_MSG_ERROR(bad value ${enableval} for enable-networking option) ;;
+esac],[RTEMS_HAS_NETWORKING=yes])
+AC_SUBST(RTEMS_HAS_NETWORKING)dnl
+])
diff --git a/aclocal/enable-posix.m4 b/aclocal/enable-posix.m4
new file mode 100644
index 0000000..1d55432
--- /dev/null
+++ b/aclocal/enable-posix.m4
@@ -0,0 +1,23 @@
+dnl $Id$
+
+AC_DEFUN([RTEMS_ENABLE_POSIX],
+[
+## AC_BEFORE([$0], [RTEMS_CHECK_POSIX_API])dnl
+
+AC_ARG_ENABLE(posix,
+[AS_HELP_STRING([--enable-posix],[enable posix interface])],
+[case "${enableval}" in 
+  yes) RTEMS_HAS_POSIX_API=yes ;;
+  no) RTEMS_HAS_POSIX_API=no ;;
+  *)  AC_MSG_ERROR(bad value ${enableval} for enable-posix option) ;;
+esac],[RTEMS_HAS_POSIX_API=yes]) 
+
+case "${host}" in
+  no_cpu-*rtems*)
+	RTEMS_HAS_POSIX_API=no
+	;;
+  *) 
+	;;
+esac
+AC_SUBST(RTEMS_HAS_POSIX_API)
+])
diff --git a/aclocal/enable-rtems-debug.m4 b/aclocal/enable-rtems-debug.m4
new file mode 100644
index 0000000..1edcea0
--- /dev/null
+++ b/aclocal/enable-rtems-debug.m4
@@ -0,0 +1,12 @@
+## $Id$
+
+AC_DEFUN([RTEMS_ENABLE_RTEMS_DEBUG],
+[
+AC_ARG_ENABLE(rtems-debug,
+AS_HELP_STRING([--enable-rtems-debug],[enable RTEMS_DEBUG]),
+[case "${enable_rtems_debug}" in
+  yes) enable_rtems_debug=yes ;;
+  no)  enable_rtems_debug=no ;;
+  *) AC_MSG_ERROR([bad value ${enable_rtems_debug} for RTEMS_DEBUG]) ;;
+esac],[enable_rtems_debug=no])
+])
diff --git a/aclocal/enable-rtemsbsp.m4 b/aclocal/enable-rtemsbsp.m4
new file mode 100644
index 0000000..d8ffc55
--- /dev/null
+++ b/aclocal/enable-rtemsbsp.m4
@@ -0,0 +1,17 @@
+dnl $Id$
+
+dnl Override the set of BSPs to be built.
+dnl used by the toplevel configure script
+dnl RTEMS_ENABLE_RTEMSBSP(rtems_bsp_list)
+AC_DEFUN([RTEMS_ENABLE_RTEMSBSP],
+[
+AC_BEFORE([$0], [RTEMS_ENV_RTEMSBSP])
+AC_ARG_ENABLE(rtemsbsp,
+[AS_HELP_STRING([--enable-rtemsbsp="bsp1 bsp2 .."],
+[BSPs to include in build])],
+[case "${enable_rtemsbsp}" in
+  yes ) enable_rtemsbsp="" ;;
+  no ) enable_rtemsbsp="no" ;;
+  *) enable_rtemsbsp="$enable_rtemsbsp" ;;
+esac],[enable_rtemsbsp=""])
+])
diff --git a/aclocal/enable-rtemsdir.m4 b/aclocal/enable-rtemsdir.m4
new file mode 100644
index 0000000..da60de7
--- /dev/null
+++ b/aclocal/enable-rtemsdir.m4
@@ -0,0 +1,16 @@
+dnl $Id$
+
+dnl XXX
+dnl RTEMS_ENABLE_RTEMSDIR(rtems_dir)
+AC_DEFUN([RTEMS_ENABLE_RTEMSDIR],
+[
+AC_BEFORE([$0], [RTEMS_SRC_DIR])
+AC_ARG_ENABLE(rtemsdir,
+[AS_HELP_STRING([--enable-rtemsdir=DIRECTORY],
+[RTEMS SOURCE DIRECTORY])],
+[case "${rtemsdir}" in
+  yes ) rtems_srcdir="" ;;
+  no ) rtems_srcdir="no" ;;
+  *) rtems_srcdir="$enableval" ;;
+esac],[rtems_srcdir=""])
+])
diff --git a/aclocal/enable-smp.m4 b/aclocal/enable-smp.m4
new file mode 100644
index 0000000..97cfef1
--- /dev/null
+++ b/aclocal/enable-smp.m4
@@ -0,0 +1,18 @@
+dnl $Id$
+
+AC_DEFUN([RTEMS_ENABLE_SMP],
+[
+## AC_BEFORE([$0], [RTEMS_CHECK_SMP])dnl
+
+AC_ARG_ENABLE(smp,
+[AS_HELP_STRING([--enable-smp],[enable smp interface])],
+[case "${enableval}" in 
+  yes) case "${RTEMS_CPU}" in
+         sparc|i386) RTEMS_HAS_SMP=no ;;
+         *)          RTEMS_HAS_SMP=no ;;
+       esac
+       ;;
+  no) RTEMS_HAS_SMP=no ;;
+  *)  AC_MSG_ERROR(bad value ${enableval} for enable-smp option) ;;
+esac],[RTEMS_HAS_SMP=no]) 
+])
diff --git a/aclocal/enable-tests.m4 b/aclocal/enable-tests.m4
new file mode 100644
index 0000000..a48168f
--- /dev/null
+++ b/aclocal/enable-tests.m4
@@ -0,0 +1,13 @@
+dnl $Id$
+
+AC_DEFUN([RTEMS_ENABLE_TESTS],
+[
+AC_ARG_ENABLE(tests,
+[AS_HELP_STRING([--enable-tests],[enable tests (default:samples)])],
+  [case "${enableval}" in
+    samples) enable_tests=samples;;
+    yes) enable_tests=yes ;;
+    no)  enable_tests=no ;;
+    *)   AC_MSG_ERROR([bad value ${enableval} for --enable-tests]) ;;
+  esac], [enable_tests=samples])
+])
diff --git a/aclocal/multilib.m4 b/aclocal/multilib.m4
new file mode 100644
index 0000000..0bbef95
--- /dev/null
+++ b/aclocal/multilib.m4
@@ -0,0 +1,17 @@
+dnl This provides configure definitions used for multilib support
+
+dnl parts of these macros are derived from newlib-1.8.2's multilib support
+
+AC_DEFUN([RTEMS_ENABLE_MULTILIB],
+[
+AC_ARG_ENABLE(multilib,
+AS_HELP_STRING([--enable-multilib],
+[build many library versions (default=no)]),
+[case "${enableval}" in
+  yes) multilib=yes ;;
+  no)  multilib=no ;;
+  *)   AC_MSG_ERROR(bad value ${enableval} for multilib option) ;;
+ esac], [multilib=no])dnl
+
+AM_CONDITIONAL(MULTILIB,test x"${multilib}" = x"yes")
+])
diff --git a/aclocal/path-ksh.m4 b/aclocal/path-ksh.m4
new file mode 100644
index 0000000..306c4ca
--- /dev/null
+++ b/aclocal/path-ksh.m4
@@ -0,0 +1,14 @@
+dnl $Id$
+
+AC_DEFUN([RTEMS_PATH_KSH],
+[
+dnl NOTE: prefer bash over ksh over sh
+AC_PATH_PROGS(KSH,bash ksh sh)
+if test -z "$KSH"; then
+dnl NOTE: This cannot happen -- /bin/sh must always exist
+AC_MSG_ERROR(
+[***]
+[    Cannot determine a usable shell bash/ksh/sh]
+[    Please contact your system administrator] );
+fi
+])
diff --git a/aclocal/project-root.m4 b/aclocal/project-root.m4
new file mode 100644
index 0000000..11643b9
--- /dev/null
+++ b/aclocal/project-root.m4
@@ -0,0 +1,25 @@
+dnl
+dnl $Id$
+dnl 
+
+dnl
+dnl PROJECT_TOPdir     .. relative path to the top of the build-tree
+dnl PROJECT_ROOT       .. relative path to the top of the temporary
+dnl                       installation directory inside the build-tree
+dnl RTEMS_TOPdir       .. relative path of a subpackage's configure.in to the
+dnl                       toplevel configure.in of the source-tree
+dnl RTEMS_ROOT         .. path to the top of a bsp's build directory
+dnl                       [Applied by custom/*.cfg, depredicated otherwise]
+dnl
+
+AC_DEFUN([RTEMS_PROJECT_ROOT],
+[dnl
+AC_REQUIRE([RTEMS_TOP])
+
+PACKHEX="\$(PROJECT_TOPdir)/tools/build/packhex"
+AC_SUBST(PACKHEX)
+
+BIN2C="\$(PROJECT_TOPdir)/tools/build/rtems-bin2c"
+AC_SUBST(BIN2C)
+])
+
diff --git a/aclocal/quoting.m4 b/aclocal/quoting.m4
new file mode 100644
index 0000000..0a95ae3
--- /dev/null
+++ b/aclocal/quoting.m4
@@ -0,0 +1,41 @@
+dnl RTEMS_CONFIGURE_ARGS_QUOTE(dnl RETURN_VAR, [ADDITIONAL_CASES], [VAR_TO_PROCESS]])
+dnl 
+AC_DEFUN([_RTEMS_CONFIGURE_ARGS_QUOTE],
+[
+$1_prune()
+{
+  # Remove --cache-file and --srcdir arguments so they do not pile up.
+  $1=
+  ac_prev=
+  for ac_arg
+  do
+    if test -n "$ac_prev"; then
+      ac_prev=
+      continue
+    fi
+    case $ac_arg in
+    -cache-file | --cache-file | --cache-fil | --cache-fi \
+    | --cache-f | --cache- | --cache | --cach | --cac | --ca | --c)
+	  ac_prev=cache_file ;;
+    -cache-file=* | --cache-file=* | --cache-fil=* | --cache-fi=* \
+    | --cache-f=* | --cache-=* | --cache=* | --cach=* | --cac=* | --ca=* \
+    | --c=*)
+      ;;
+    --config-cache | -C)
+      ;;
+    -srcdir | --srcdir | --srcdi | --srcd | --src | --sr)
+	  ac_prev=srcdir ;;
+    -srcdir=* | --srcdir=* | --srcdi=* | --srcd=* | --src=* | --sr=*)
+      ;;
+    m4_if([$2],,,[$2])
+    *) $1="$$1 '$ac_arg'" ;;
+    esac
+  done
+  export $1
+}
+])
+
+AC_DEFUN([RTEMS_CONFIGURE_ARGS_QUOTE],[
+m4_expand_once([_RTEMS_CONFIGURE_ARGS_QUOTE([$1],[$2])])
+eval $1_prune m4_if([$3],,[$ac_configure_args],[[$]$3])
+])
diff --git a/aclocal/rpm.m4 b/aclocal/rpm.m4
new file mode 100644
index 0000000..1f2015b
--- /dev/null
+++ b/aclocal/rpm.m4
@@ -0,0 +1,20 @@
+AC_DEFUN([RTEMS_ENABLE_RPMPREFIX],[
+AC_ARG_ENABLE([rpmprefix],
+[  --enable-rpmprefix=<rpmprefix>      prefix rpms],
+[case $enable_rpmprefix in
+yes ) rpmprefix="rtems-"]_RTEMS_API["-";;
+no ) rpmprefix="%{nil}";;
+* ) AS_IF([test -z "$enable_rpmprefix"],
+      [rpmprefix="%{nil}"],
+      [rpmprefix="$enable_rpmprefix"]);;
+esac],
+[rpmprefix="rtems-"]_RTEMS_API["-"])
+
+AC_ARG_ENABLE([osversions],
+[  --enable-osversions       whether to use version numbers in os-tripples],
+[case $enable_osversions in
+yes ) osversion=_RTEMS_API;;
+* ) osversion=;;
+esac],
+[osversion=_RTEMS_API])
+])
diff --git a/aclocal/rtems-top.m4 b/aclocal/rtems-top.m4
new file mode 100644
index 0000000..c6acfd1
--- /dev/null
+++ b/aclocal/rtems-top.m4
@@ -0,0 +1,36 @@
+dnl $Id$
+
+# AC_DISABLE_OPTION_CHECKING is not available before 2.62
+AC_PREREQ(2.62)
+
+dnl
+dnl RTEMS_TOP($1)
+dnl 
+dnl $1 .. relative path from this configure.in to the toplevel configure.in
+dnl
+AC_DEFUN([RTEMS_TOP],
+[dnl
+AC_REQUIRE([RTEMS_VERSIONING])
+AC_REQUIRE([AC_DISABLE_OPTION_CHECKING])
+AC_CONFIG_AUX_DIR([$1])
+AC_CHECK_PROGS(MAKE, gmake make)
+AC_BEFORE([$0], [AM_INIT_AUTOMAKE])dnl
+
+AC_PREFIX_DEFAULT([/opt/rtems-][_RTEMS_API])
+
+RTEMS_TOPdir="$1";
+AC_SUBST(RTEMS_TOPdir)
+
+dots=`echo $with_target_subdir|\
+sed -e 's,^\.$,,' -e 's%^\./%%' -e 's%[[^/]]$%&/%' -e 's%[[^/]]*/%../%g'`
+PROJECT_TOPdir=${dots}${RTEMS_TOPdir}/'$(top_builddir)'
+AC_SUBST(PROJECT_TOPdir)
+
+PROJECT_ROOT="${RTEMS_TOPdir}/\$(top_builddir)"
+AC_SUBST(PROJECT_ROOT)
+
+AC_MSG_CHECKING([for RTEMS Version])
+AC_MSG_RESULT([_RTEMS_VERSION])
+pkgdatadir="${datadir}"/rtems[]_RTEMS_API;
+AC_SUBST([pkgdatadir])
+])dnl
diff --git a/aclocal/tool-paths.m4 b/aclocal/tool-paths.m4
new file mode 100644
index 0000000..ff6e5f8
--- /dev/null
+++ b/aclocal/tool-paths.m4
@@ -0,0 +1,23 @@
+AC_DEFUN([RTEMS_TOOLPATHS],
+[
+# tooldir='$(exec_prefix)/'$target_alias
+# Temporary work-around until building in source tree is supported
+AC_REQUIRE([RTEMS_PROJECT_ROOT])
+
+tooldir='$(PROJECT_ROOT)'
+AC_SUBST(tooldir)
+
+project_includedir='$(tooldir)'/include
+AC_SUBST(project_includedir)
+
+project_libdir='$(tooldir)/lib$(MULTISUBDIR)'
+AC_SUBST(project_libdir)
+
+project_bindir='$(tooldir)/bin'
+AC_SUBST(project_bindir)
+
+rtems_bspdir='$(prefix)/${RTEMS_BSP}'
+AC_SUBST(rtems_bspdir)
+rtems_makedir='$(prefix)/make'
+AC_SUBST(rtems_makedir)
+])
diff --git a/aclocal/version.m4 b/aclocal/version.m4
new file mode 100644
index 0000000..6ca81ac
--- /dev/null
+++ b/aclocal/version.m4
@@ -0,0 +1,4 @@
+AC_DEFUN([RTEMS_VERSIONING],
+m4_define([_RTEMS_VERSION],[4.10.99.0]))
+
+m4_define([_RTEMS_API],[4.11])